Как включить Песочницу в Windows 10 Домашняя

Обновлено 20.01.2023 windows

Песочница в Windows 10 домашняя Песочница Windows 10 — одно из самых интересных и полезных нововведений в последней версии ОС. К сожалению, по умолчанию она доступна только в Профессиональной (Pro) и Корпоративной (Enterprise) версиях системы. Тем не менее, при желании, вы можете установить песочницу Windows 10 (Windows Sandbox) и в домашней редакции системы.

В этой инструкции подробно о том, как включить песочницу в Windows 10 Home с помощью простого скрипта. Непосредственно о том, что такое «Песочница», об использовании этой функции и некоторых дополнительных нюансах в отдельной статье Песочница Windows 10 (Windows Sandbox).

Установка Песочницы в Windows 10 Home

Прежде чем приступить к установке Песочницы в Windows 10 Домашняя, рекомендую учесть следующие моменты:

Для работы Песочницы требуется включенная виртуализация в БИОС/UEFI. Подробнее: Как включить виртуализацию.
При тестах данного способа установки песочницы я столкнулся с тем, что её удаление и откат сделанных изменений оказывается затруднительным (точнее — не удалось полностью удалить все следы). Возможно, помогут заранее созданные точки восстановления, но гарантий дать не могу. Либо используйте функцию удаления Песочницы, которая реализована в самом скрипте.
Гарантировать исправную работу Песочницы после установки данным способом нельзя. Например, можно столкнуться с ошибкой Не удалось инициализировать Песочницу Windows и другими.

Для установки песочницы в Windows 10 Домашняя можно использовать простой bat-файл, который, с помощью DISM установит все необходимые компоненты в домашней версии системы. Такой файл можно сделать самостоятельно, используя код, приведенный ниже (см. Как создать bat файл).

@echo off

echo Checking for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

echo Permission check result: %errorlevel%

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"

echo Running created temporary "%temp%\getadmin.vbs"
timeout /T 2
"%temp%\getadmin.vbs"
exit /B

:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0" 

echo Batch was successfully started with admin privileges
echo .
cls
GOTO:menu
:menu
Title Sandbox Installer
echo Select Action
echo 1 Install
echo 2 Uninstall
echo 3 Exit
set /p uni= Enter your option:
if %uni% ==1 goto :in
if %uni% ==2 goto :un
if %uni% ==3 goto :ex

:in
cls
Title Install Sandbox

pushd "%~dp0"

dir /b %SystemRoot%\servicing\Packages\*Containers*.mum >sandbox.txt

for /f %%i in ('findstr /i . sandbox.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"

del sandbox.txt

Dism /online /enable-feature /featurename:Containers-DisposableClientVM /LimitAccess /ALL /NoRestart

goto :remenu

:un
cls
Title Uninstall Sandbox

pushd "%~dp0"

Dism /online /disable-feature /featurename:Containers-DisposableClientVM /NoRestart

dir /b %SystemRoot%\servicing\Packages\*Containers*.mum >sandbox.txt

for /f %%i in ('findstr /i . sandbox.txt 2^>nul') do dism /online /norestart /remove-package:"%SystemRoot%\servicing\Packages\%%i"

del sandbox.txt

goto :remenu

:remenu
cls
echo Restart computer?
echo 1 Yes
echo 2 No
set /p uni= Input 1 or 2:
if %uni% ==1 goto :re
if %uni% ==2 goto :ex

:re
shutdown /r /t 0 /f
goto :ex

:ex
exit

А при желании его можно скачать с сайта автора скрипта (сайт на немецком, ссылка на загрузку — Sandbox Installer.zip на указанной странице). После запуска файла от имени администратора потребуется выбрать опцию установки (Install), введя 1 и дождаться завершения процесса.

Установка Windows Sandbox в домашней редакции системы

После завершения установки компонентов вам будет предложено перезагрузить компьютер, сделайте это (в текущей версии скрипта требуется ввести 1 для подтверждения перезагрузки). При перезагрузке будет проведена настройка системы и новых компонентов, а после неё вы увидите новый пункт в меню «Пуск» — Windows Sandbox, запускающий песочницу.

О возможных ошибках (например, 0x80070002 «Не удается найти указанный файл») при запуске, их исправлении и возможностях настройки песочницы в упоминавшейся выше инструкции про использование песочницы Windows 10.

Комментарии (34) к Как включить Песочницу в Windows 10 Домашняя

Михаил
15.09.2019 в 15:59
Windows 10 Home
При запуске вызвало ошибку:
«Подключение к песочнице прервано.
Error 0x80072746. Удаленный хост принудительно разорвал существующее подключение.
Вы хотите отправить отзыв об этой проблеме?» (Да/Нет)
Не может ли это быть отказом сервера работать именно с хоум-эдишен?
Ответить
- Dmitry
  16.09.2019 в 11:03
  Не похоже (но не исключено, конечно). Вообще, такая ошибка обычно бывает (когда с виртуальными машинами работаешь в 10 Pro, а песочница — и есть виртуальная машина), если что-то меняется в параметрах сети во время работы, либо блокируется сеть виртуальная сторонним софтом (антивирусы, брандмауэры и т.п.).
  Ответить
Wan
07.10.2019 в 03:25
Такая же бадяга с разрывом. Блокираторов не имею.
Ответить
IT Simply
01.11.2019 в 12:35
В статье допущен ряд ошибок. Для начала — всю операцию лучше проводить в командной строке, а не в батнике. Сначала предоставлю исправленный набор команд, а потом дам комментарии:
```
dir /b %SystemRoot%\servicing\Packages\*Containers*.mum >sandbox.txt

for /f %i in ('findstr /i . sandbox.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%i"

del sandbox.txt

dir /b %SystemRoot%\servicing\Packages\*HyperV*.mum >hv.txt

for /f %i in ('findstr /i . hv.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%i"

del hv.txt

dir /b %SystemRoot%\servicing\Packages\*Hyper-V*.mum >h-v.txt

for /f %i in ('findstr /i . h-v.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%i"

del h-v.txt

dir /b %SystemRoot%\servicing\Packages\*remote*.mum >remote.txt

for /f %i in ('findstr /i . remote.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%i"

del remote.txt

set REGWAY="HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Containers\CmService\Policy"

reg add %REGWAY% /v DisableClone /t REG_DWORD /d 1

reg add %REGWAY% /v DisableSnapshot /t REG_DWORD /d 1

pause

exit
```
Теперь комментарий:
1) В статье не учитывается тот момент, что для песочницы требуется Hyper-V. Поскольку этой виртуальной машины тоже нет в домашней редакции, то и этот компонент тоже нужно восстановить и включить в компонентах.
2) Последние 2 команды, которые редактируют реестр, дают возможность использовать песочницу на «проблемном» железе — например, на виртуалке с системными требованиями ниже заявленных. Тестировал лично.
3) Точки восстановления для данной операции не нужны, потому что система по-факту не устанавливает что-то, а «активирует» то, что уже есть, но заблокировано из-за ограничений домашней редакции.
4) В статье ни слова не сказано о том, что нужно включить виртуализацию в настройках BIOS/UEFI
Ответить
- Иван
  03.03.2020 в 21:46
  Спасибо за набор команд.
  Ответить
- Павел
  18.04.2020 в 17:52
  for /f %i in (‘findstr /i . sandbox.txt 2^>nul’) do dism /online /norestart /add-package:»%SystemRoot%\servicing\Packages\%i»
  В это строке какая-то ошибка.
  Вы сами то тестировали свой скрипт?
  Ответить
  - Dmitry
    18.04.2020 в 18:02
    Строка выглядит так (кавычки имеют значение, в вашем примере один знак %i):
    for /f %%i in ('findstr /i . sandbox.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
    Тестировал при написании статьи, скриншот в статье как раз из командной строки при тесте, установка прошла успешно. Сейчас перепроверить не могу, только Pro под рукой.
    Хотя.. вот, запустил в виртуалке с Pro 1909 (ошибки-то покажет и в ней), скопировав содержимое bat прямо из статьи, результат — все пакеты по порядку установились, ни одной ошибки.
    Ответить
    - Павел
      18.04.2020 в 18:52
      спасибо
      вопрос был адресован IT Simply
      там опечатка в скрипте
      Ответить
  - Zxcrges
    04.09.2023 в 12:51
    А вы можете просто, правильную версию кода дать? У меня ошибка в sandbox по типу «не удалось инициализировать песочницу windows» но Hyper-V включён и все нужное включено. Что делать не знаю.
    Ответить
- Павел
  18.04.2020 в 18:22
  По аналогии с немецким скриптом в некоторых местах (не везде) надо % заменить на %%
  Ответить
- PCuser239
  06.09.2020 в 09:50
  Подскажите, пожалуйста, а как восстановить компонент Hyper-V? В открытом доступе нигде не нашёл :(
  Ответить
- аноним
  12.03.2023 в 17:42
  Что делать если пишет не удалось инициализировать песочницу виндовс???
  Ответить
- Sergey
  30.12.2023 в 03:35
  вместо %i надо %%i
  Ответить
Андрей
15.12.2019 в 16:16
Да уж! И песочница не заработала, и блюстакс теперь не стартует даже после удаления песочницы :(
Ответить
- Dmitry
  16.12.2019 в 09:23
  Отключите компоненты hyper-v в компонентах, должен заработать после этого.
  Ответить
  - Andrey
    17.12.2019 в 23:24
    Отключал конечно, перезагружал, кучу вариантов с сайтов перелопатил — всё бесполезно. И, кстати, это известная проблема с песочницей и блюстаксом. В общем, полирнул систему и БС заработал )
    Ответить
    - Sanya
      17.05.2020 в 19:34
      как полирнуть систему?
      Ответить
  - Константин
    14.03.2021 в 23:39
    Чтобы заработал BlueStacks после отключения песочницы надо не только отключить Hyper-V и ещё компонент «Платформа виртуальной машины» находится также в «Компоненты Windows»
    Ответить
Безудержный
28.10.2021 в 12:53
Добрый день!
Попробовал метод в статье и по официальной ссылке, но программа не останавливается, только устанавливает обновления раз за разом, сообщения о успешной установке нет.
вариант из комментариев просто не запускается!
Винда 10 Домашняя. Как сделать, чтобы работало?
Ответить
Матвей
07.03.2022 в 19:05
Ошибка 2 что делать?
Ответить
Тимофей
03.10.2022 в 10:27
Что делать если пишет не удалось инициализировать песочницу виндовс???
Ответить
- Dmitry
  03.10.2022 в 19:12
  Здравствуйте.
  А включена виртуализация?
  Ответить
Виктор
20.12.2022 в 23:34
Круто, теперь сижу и думаю, что делать с черным экраном при запуске.
Ответить
- Dmitry
  21.12.2022 в 16:11
  В какой момент он появляется? Простое ожидание никак не влияет?
  Ответить
Роман
04.01.2023 в 13:38
здравствуйте, при запуске пишет «не удалось инициализировать песочницу windows» что делать? (если что то у меня windows 11 домашняя)
Ответить
чел
15.07.2023 в 23:54
а что если пишет не удалось инициализировать песочницу windows? помогите пожалуйста!
Ответить
- Dmitry
  16.07.2023 в 11:08
  Здравствуйте.
  А виртуализация на компьютере включена при этом?
  Ответить
  - никита
    06.08.2023 в 16:30
    да, но нету компонентов хайпер в не подскажите как их установить?
    Ответить
    - Dmitry
      07.08.2023 в 14:41
      Их нет в Домашней. Вот здесь описан один из способов включить (на момент написания статьи работал): https://remontka.pro/hyper-v-enable-disable-windows/
      Но вот не уверен, что у вас причина проблемы именно в этом.
      Ответить
Никита
15.11.2023 в 18:44
К сожалению данная инструкция не сработала. Песочница установилась, но при запуске выпадает окно с формулировкой «Не удалось инициализировать песочницу Windows».
Мой ноутбук соответствует всем минимальным системным требованиям для запуска песочницы Windows, а именно: необходим минимум 2-х ядерный процессор — у меня 4-х ядерный AMD Ryzen 5 3550H; минимум 4 ГБ ОЗУ — у меня 8 ГБ; минимум 1 ГБ свободного места на системном разделе — у меня 342 ГБ свободного места; необходимо включить виртуализацию в BIOS/UEFI — у меня она включена.
Так же я установил все компоненты, связанные с Hyper-V, а именно: Платформа Hyper-V и Средства управления Hyper-V. Но это тоже абсолютно не помогло и ошибка не перестала появляться.
Ещё, я попробовал в окне «Включение и отключение компонентов Windows» включить следующие компоненты: Платформа виртуальной машины и Платформа низкоуровневой оболочки Windows, но это тоже не помогло исправить данную проблему.
Может у вас есть какие-нибудь другие решения данной проблемы?
Ответить
Георгий
07.03.2025 в 21:27
ошибка No mapping between account names and security IDs was done. (0x80070534)
Ответить
Тимур
28.04.2025 в 16:59
Как удалить код???? Он мало того что не сработал, так еще и комп после перезагрузки стал дико виснуть и вылетает ВСЕГДА синий экран смерти. Не советую этот код скачивать или зайдите на другой скайт. А авторы, как удалить песочницу теперь? Откат обновления поможет?
Ответить
- Dmitry
  28.04.2025 в 18:30
  Здравствуйте.
  1. При запуске .bat файла есть опция удаления (Uninstall)
  2. Ещё одним быстрым вариантом будет использование точек восстановления, если они есть.
  Ответить
Федор
27.07.2025 в 08:57
а сколько загрузка должна идти? у меня загружается бесконечно как будто
Ответить

Оставить комментарий